問題2-56

記号微分に関する問題です。quoteを使った記号表現だけで微分計算をやってしまうという点に面白味を感じました。まずは、本書に出てきた例文をコピペします。

(define (=number? exp num)
  (and (number? exp) (= exp num)))

(define (variable? x) (symbol? x))

(define (same-variable? v1 v2)
  (and (variable? v1) (variable? v2) (eq? v1 v2)))

(define (make-sum a1 a2)
  (cond ((=number? a1 0) a2)
        ((=number? a2 0) a1)
        ((and (number? a1) (number? a2)) (+ a1 a2))
        (else (list '+ a1 a2))))

(define (make-product m1 m2)
  (cond ((or (=number? m1 0) (=number? m2 0)) 0)
        ((=number? m1 1) m2)
        ((=number? m2 1) m1)
        ((and (number? m1) (number? m2)) (* m1 m2))
        (else (list '* m1 m2))))

(define (sum? x)
  (and (pair? x) (eq? (car x) '+)))

(define (addend s) (cadr s))
(define (augend s) (caddr s))

(define (product? x)
  (and (pair? x) (eq? (car x) '*)))

(define (multiplier p) (cadr p))
(define (multiplicand p) (caddr p))

(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)
         (make-sum
          (make-product (multiplier exp)
                        (deriv (multiplicand exp) var))
          (make-product (deriv (multiplier exp) var)
                        (multiplicand exp))))
        (else
         (error "unknown expression type -- DERIV" exp))))

(deriv '(+ x 3) 'x)  ;=>1
(deriv '(* x y) 'x)  ;=>y
(deriv '(* (* x y) (+ x 3)) 'x)  ;=>(+ (* x y) (* y (+ x 3)))

上記の手続きだけでは、べき乗を扱うことができません。それをできるように拡張するのが問題2-56です。以下のように、derivを修正しました。

(define (make-exponentiation b e)
  (cond ((= e 0) 1)
        ((= e 1) b)
        (else (list '** b e))))

(define (exponentiation? ex)
  (and (pair? ex) (eq? (car ex) '**)))

(define (base ex) (cadr ex))
(define (exponent ex) (caddr ex))

(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)
         (make-sum
          (make-product (multiplier exp)
                        (deriv (multiplicand exp) var))
          (make-product (deriv (multiplier exp) var)
                        (multiplicand exp))))
        ((exponentiation? exp)
         (make-product (make-product (exponent exp)
                                     (make-exponentiation (base exp) (- (exponent exp) 1)))
                       (deriv (base exp) var)))
        (else
         (error "unknown expression type -- DERIV" exp))))

(deriv '(** x 0) 'x)  ;=>0
(deriv '(** x 1) 'x)  ;=>1
(deriv '(** x 2) 'x)  ;=>(* 2 x)
(deriv '(** x 3) 'x)  ;=>(* 3 (** x 2))
(deriv '(* 2 (** x 3)) 'x)  ;=>(* 2 (* 3 (** x 2)))

最後の式は、6xの二乗が返ってきて欲しいところですが、それをやるためにはもう一工夫が必要なのでしょう。
次の問題では、複数の値の和や積を扱えるように拡張しなければなりませんが、p59のドット末尾記法(dotted-tail notation)を使えば上手くいきそうです。しかし、引数をリストとして扱わなければならない分、チェックがいろいろと面倒くさそうなので、しっかりと考えてみたいと思っています。